Pass Schedule Calculation for a Hot Rolling Reversing Mill


Language: Fortran IV.

Objective: Pass Schedule Calculation for a Pilot Flat Hot Rolling Reversing Mill, using the method of Sims to calculate the loads.


***** Begin of Program Listing *****

C
C ***
C ***
C ***      PASS SCHEDULE CALCULATION FOR A HOT ROLLING REVERSING MILL
C ***
C ***
C ***
C ***      References:
C ***
C ***        . SILVA, R.C.R. et alii: Determinacao da Sequencia de
C ***          Passes na Laminacao a Quente de Placas de Aco;
C ***          Metalurgia ABM, Maio 1983, 267-271.
C ***
C ***        . SEREDYNSKI, F.: Performance Analysis and Optimization
C ***          of the Plate-Rolling Process. In: Mathematical
C ***          Process Models in Iron and Steelmaking, London, Metals
C ***          Society, 19-21, 1973.
C ***
C ***        . BUCKLEY, G.W. et al.: Dynamic Analysis and Performance
C ***	       of Hot Rolling Mills; Metals Technology, July 1978,
C ***          228-250.
C ***
C ***        . TSELIKOV, A. : Stress and Strain in Metal Rolling;
C ***          Editorial MIR, Moscou, 1967.
C ***
C ***        . PLAUT, R.L.: Laminacao dos Acos - Topicos Avancados;
C ***          ABM, Sao Paulo, 1983.
C ***
C ***
C ***                               
C ***
C ***               Antonio Augusto Gorni --- October 6, 1986
C ***
C ***
C 
C
C ***   FUNCAO ARCOS(X):  Arco-cosseno de X, em radianos.
C 
      FUNCTION ARCOS(X)
      ARCOS=ATAN(SQRT(1.-X*X)/X)
      RETURN
      END
C
C ***   FUNCAO TAN(X): Tangente de X, em radianos.
C
      FUNCTION TAN(X)
      TAN=SIN(X)/COS(X)
      RETURN
      END
C
C ***   FUNCAO TEM(A,B,C):  Calculo da Nova Temperatura da Tira.
C ***
C ***          PARAMETROS:
C ***
C ***        . A ==> Temperatura, Graus Celsius.
C ***        . B ==> Tempo, Segundos.
C ***        . C ==> Espessura da Tira, mm.
C ***
C ***
C ***    Para maiores detalhes consulte SEREDYNSKI e PLAUT.
C ***
C
      FUNCTION TEM(A,B,C)
      E=A/1000.*(0.125*A/1000.-0.38)+1.1
      RO=8050.-0.5*A
      CE=587.8+0.0683*A
      TKK=6.*5.66E-5*E/(RO*CE*C)
      A=A+273.
      TEM=A/(1.+TKK*A*A*A*B)**0.333333
      TEM=TEM-273.
      A=A-273.
      RETURN
      END
C
C ***     SUBROTINA TEMP: Calculo das Temperaturas em Diversos
C ***                     Pontos da Tira.
C ***
C ***         PARAMETROS:
C ***
C ***          . T1 ==> Temperatura Inicial, Cabeca da Tira, .C.
C ***          . T2 ==> Temperatura Inicial, Cauda da Tira, .C.
C ***          . T3 ==> Temperatura Passe Anterior, Cabeca, .C.
C ***          . T4 ==> Temperatura Passe Anterior, Cauda, .C.
C ***          . T5 ==> Temperatura Passe Atual, Cabeca, .C.
C ***          . T6 ==> Temperatura Passe Atual, Cauda, .C.
C ***          . H1 ==> Espessura Anterior, mm.
C ***          . H2 ==> Espessura Atual, mm.
C ***          . RPM ==> Rotacao dos Cilindros, rpm.
C ***          . LO ==> Comprimento Inicial da Tira, mm.
C ***          . LN ==> Comprimento Atual da Tira, mm.
C ***          . DELT ==> Tempo de Reversao do Laminador, s.
C ***          . I ==> Numero do Passe.
C
      SUBROUTINE TEMP(T1,T2,H1,H2,RPM,LO,DELT,T3,T4,T5,T6,LN,I)
      REAL LO,LN
      DIMENSION N(50)
      N(1)=1
      DO 1 J=2,50
    1 N(J)=N(J-1)+2
      T3=TEM(T1,DELT,H1)
      T4=TEM(T2,DELT,H1)
      LN=2*H1*LO/(H1+H2)
      TEMPO=LN*60./(2733.1855*RPM)
      DO 2 J=1,50
      NN=N(J)
      IF(I-NN)3,4,3
    4 T5=TEM(T4,TEMPO,H2)
      T6=TEM(T3,TEMPO,H1)
      GO TO 5
    3 CONTINUE
    2 CONTINUE
      T5=TEM(T4,TEMPO,H1)
      T6=TEM(T3,TEMPO,H2)
    5 CONTINUE
      LN=LO*H1/H2
      RETURN
      END
C
C ***          P R O G R A M A        P R I N C I P A L
C ***
C ***
C ***       ALGUMAS VARIAVEIS:
C ***
C ***     . D ==> Diametro do Cilindro, mm.
C ***     . V ==> Velocidade Maxima dos Cilindros, m/s.
C ***     . VA ==> Velocidade Minima dos Cilindros, m/s.
C ***     . ALFA ==> Coefiente de Expansao Termica da Tira, mm/.C.
C ***     . DH ==> Variacao Padrao de Espessura, mm.
C ***     . RMAX ==> Maior Reducao Permissivel, %.
C ***     . RMIN ==> Menor Reducao no Ultimo Passe, %.
C ***     . ABMIN ==> Menor Abertura Permissivel, mm.
C ***     . AX ==> Constante Empirica de Mordida.
C ***     . XM ==> Modulo de Rigidez da Cadeira, kgf/mm.
C ***     . PMAX ==> Carga Maxima do Laminador, kgf.
C ***     . ERMAX ==> Potencia Maxima do Laminador, kW.
C ***     . H1 ==> Espessura da Placa Original, mm.
C ***     . H2 ==> Espessura do Esboco Final, mm.
C ***     . W ==> Largura da Tira, mm.
C ***     . LO ==> Comprimento Original da Placa, mm.
C ***     . A(i) ==> Coeficientes Equacao de Escoamento.
C ***     . CFATR ==> Coeficiente de Atrito no Mancal para Duo.
C ***     . CTRANS ==> Rendimento da Transmissao.
C ***     . RMOT ==> Rendimento do Motor Eletrico.
C ***
C ***
C ***   OBSERVACOES:
C ***
C ***     - AX e' uma constante empirica para o calculo do angulo de
C ***       mordida do laminador; seu valor padrao e' um.
C ***
C ***     - DH e' um valor padrao de reducao de espessura. 
C ***
C ***     - Esta versao do Programa foi especialmente adaptada para
C ***       o caso da Laminacao a Quente efetuada em Laminador Piloto
C ***       Duo. Caso for re-adaptado `as condicoes industriais a 
C ***       equacao do angulo de mordida devera' ser corrigida. O 
C ***       calculo das perdas por atrito (validas para laminador duo)
C ***       e na caixa de transmissao certamente tera' de ser revisado.
C ***
C
      PROGRAM PCALC
      REAL LO,LN,LAUX,LL
      LOGICAL RESP
      DIMENSION H(50),DEH(50),VEL(50),TC(50),TP(50),P(50),TORQ(50),
     >NN(50),T77(50),T88(50),R(50),PAR(50),WW(50),PP(50),DRE(50),
     >DFR(50),MS(40),WL(50),ERN(50),DL(50),M(50),AI(11)
      DATA AI/-15.32,16429.7,2.61,1.04/,ALFA/11.2E-6/,XM/511.E3/,
     >PMAX/2.E6/,ERMAX/11700./,AX/1./,RMIN/10./,ABMIN/0.99/,
     >CFATR/0.01/,CTRANS/0.95/,RMOT/0.95/
      RMIN=RMIN/100.
 1444 CALL HOME
      CALL BEEP(20,15)
C
C *** ENTRADA DOS DADOS.
C
      WRITE(1,1000)
 1000 FORMAT(' PASS SCHEDULE CALCULATION FOR HOT ROLLING REVERSING'
     >' MILL',//
     >/,' WORK ROLL DIAMETER (MM)? ')
      READ(1,1010)D
 1010 FORMAT(F6.0)
      WRITE(1,1020)
 1020 FORMAT(' INITIAL THICKNESS (MM)? ')
      READ(1,1010)H1
      WRITE(1,1030)
 1030 FORMAT(' FINAL THICKNESS (MM)? ')
      READ(1,1010)H2
      WRITE(1,1040)
 1040 FORMAT(' ROLLING STOCK WIDTH (MM)? ')
      READ(1,1010)W
      WRITE(1,1050)
 1050 FORMAT(' WORK ROLLS MAXIMUM PERIPHERICAL SPEED (M/S)? ')
      READ(1,1010)V
      WRITE(1,1115)
 1115 FORMAT(' WORK ROLLS MINIMUM PERIPHERICAL SPEED (M/S)? ')
      READ(1,1010)VA
      WRITE(1,1060)
 1060 FORMAT(' MINIMUM STANDARD VALUE OF ROLL GAP (MM)? ')      
      READ(1,1010)DH
      WRITE(1,1070)
 1070 FORMAT(' INITIAL TEMPERATURE OF ROLLING STOCK HEAD (.C)? ')
      READ(1,1010)T1
      WRITE(1,1080)
 1080 FORMAT(' FINAL TEMPERATURE OF ROLLING STOCK TAIL (.C)? ')
      READ(1,1010)T2
      WRITE(1,1090)
 1090 FORMAT(' REVERSING TIME (S)? ')
      READ(1,1010)DELT
      WRITE(1,1100)
 1100 FORMAT(' INITIAL ROLLING STOCK LENGTH (MM)? ')
      READ(1,1010)LO
      WRITE(1,1110)
 1110 FORMAT(' MAXIMUM STRAIN (%)? ')
      READ(1,1010)RMAX
      RMAX=RMAX/100.
 3859 WRITE(1,1283)
 1283 FORMAT(' MAXIMUM NUMBER OF PASSES? ')
      READ(1,1025)NPAS
      IF(NPAS.LT.51)GO TO 8497
      CALL BEEP(20,15)
      WRITE(1,3927)NPAS
 3927 FORMAT(/,' NUMBER OF PASSES (',I3,') MUST BE LOWER THAN 50.',/,
     >' REENTRE!',/)
      GO TO 3859
 8497 WRITE(1,3987)
 3987 FORMAT(' ODD NUMBER OF PASSES (0 -> NO; 1 -> YES)? ')
      READ(1,1025)NPASS
      WRITE(1,1085)
 1085 FORMAT(' MATERIAL IDENTIFICATION MESSAGE? ')
      READ(1,1095)MS
 1095 FORMAT(40A2)
      WRITE(1,1015)
 1015 FORMAT(' DO YOU WANT TO PRINT RESULTS (0 -> NO; 1 -> YES)? ')
      READ(1,1025)IS
 1025 FORMAT(I2)
      WRITE(1,3948)
 3948 FORMAT(' DO YOU WANT TO DISPLAY INTERMEDIATE RESULTS? ',/,
     >' (0 -> NO; 1 -> YES) ')
      READ(1,1025)INTER
      IF(IS.EQ.1)GO TO 1035
      IS=1
      GOTO 1045
 1035 IS=2
 1045 CALL BEEP(20,15)
      CALL HOME
      LAUX=LO
C
C *** IMPRESSAO OPCIONAL DO CABECALHO
C
      IF(IS.NE.2)GO TO 9879
      CALL BEEP(20,15)
      WRITE(1,1055)
 1055 FORMAT(///,' PREPARE PRINTER, MARK START OF REPORT, ',
     >'THEN PRESS RETURN.',//)
      READ(1,1495)IE
      WRITE(2,1065)
 1065 FORMAT(19X,'PASS SCHEDULE FOR HOT ROLLING REVERSING MILL',//,30X,
     >'VERSAO III, OCTOBER 1986',//,31X,'ANTONIO AUGUSTO GORNI',////,
     >' ROLLING MILL DATA:',/)
      AUX=RMAX*100.
      AUX2=V*60.
      AUX3=VA*60.
      WRITE(2,1005)D,XM,AUX2,AUX3,AUX,DELT,PMAX,ERMAX
 1005 FORMAT(' WORK ROLL DIAMETER (MM) = ',F5.0,5X,'ROLLING MILL STIFNESS',
     > (KGF/MM) = ',F9.0,/,' MAX. ROLL SPEED (M/MIN) = '
     >,F4.0,6X,'MIN. ROLL SPEED (M/MIN) = ',F3.0,/,' MAXIMUM STRAIN ', 
     >'(%) = ',F4.1,15X,'REVERSING TIME (S) = ',F3.0,/,' MAXIMUM LOAD',
     > (KGF) = ',F9.0,10X,'MAXIMUM POWER (KW) = ',F6.0)
 1139 FORMAT(' HEAD TEMPERATURE (.C) = ',F5.0,8X,' TAIL TEMPERATURE',
     >' (.C) = ',F5.0,/)
      WRITE(2,1254)MS
 1254 FORMAT(///' MATERIAL TO BE ROLLED: ',//,1X,40A2)
      WRITE(2,5488)H1,H2,W,LO
 5488 FORMAT(' INITIAL THICKNESS (MM) = ',F5.1,9X,' FINAL THICKNESS (MM)
     > = ',F5.1,/,' WIDTH (MM) = ',F5.0,20X,
     >'INITIAL LENGTH (MM) = ',F5.0)
      WRITE(2,1139)T1,T2
C
C *** INICIALIZACAO DAS VARIAVEIS.
C
 9879 D2=D
      NK=1
      NN(1)=1
      DO 20 I=2,NPAS
   20 NN(I)=NN(I-1)+2
   61 DO 2 I=1,NPAS
      WW(I)=0.
      DEH(I)=DH
    2 VEL(I)=V
      T88(1)=T2
      T77(1)=T1
C
C *** 'LOOP' PARA CALCULO DO ESQUEMA DE PASSES.
C
   60 LO=LAUX
      DO 30 I=2,NPAS
      IF(I-NPAS)86,1555,1555
 1555 IAUX=I-1
      WRITE(1,1556)IAUX
 1556 FORMAT(//,' EXCESSIVE (',I2,') E'' NUMBER OF PASSES!',/)
   87 CALL BEEP(20,15)
      WRITE(1,88)
   88 FORMAT(' PROPOSED PASS SCHEDULE IS UNFEASIBLE!')
      GO TO 759
   86 CONTINUE
C
C *** DETERMINACAO DAS ESPESSURAS PARA CALCULOS.
C
      H(1)=H1
   51 T8=T88(I-1)
      T7=T77(I-1)
      HI=H(I-1)
      IF(H(I-1)-DH)80,80,14
   80 H(I)=H2
      GO TO 81
   14 H(I)=H(I-1)-DEH(I-1)
      IF(H(I)-H2)41,41,81
   41 H(I)=0.999*H2
   81 CONTINUE
      HF=H(I)
C
C *** LIMITACAO DE REDUCAO DEVIDO `A FALTA DE DUTILIDADE.
C
      IF((HI-HF)/HI-RMAX)92,92,93
   93 H(I)=(1.-RMAX)*HI
      HF=H(I)
   92 CONTINUE
      HHI=H(I-1)
      HHF=H(I)
C
C *** COMPENSACAO DA PENETRACAO INCOMPLETA DA DEFORMACAO.
C
      LA=SQRT(D*(HI-HF)/2.)
      IF((HI+HF)/2.-LA)94,94,95
   95 COMP=(HI-HF)/2.
      HI=LA+COMP
      HF=LA-COMP
   94 CONTINUE
      RPM=19098.593*VEL(I-1)/D
C
C *** CALCULO DA QUEDA DE TEMPERATURA DO ESBOCO.
C
      CALL TEMP(T7,T8,HHI,HHF,RPM,LO,DELT,T3,T4,T5,T6,LN,I)
      T77(I)=T6
      T88(I)=T5
      TC(I-1)=T3
      TP(I-1)=T4
      IF(T3-T4)5,6,6
    5 C=T3
      GO TO 7
    6 C=T4
C
C *** CALCULO DE PRESSAO DE LAMINACAO PELO MODELO DE SIMS.
C
    7 LL=LO
      LO=LN
      V=1000.*VEL(I-1)
      EP=ALOG(HI/HF)
      RA=V*SQRT(2./(D*(HI-HF)))*EP
      IF(EP.GE.0.05)GO TO 56
      EP=0.05
   56 IF(RA.GE.1.5)GO TO 57
      RA=1.5
   57 EP=100.*EP
      ES=(AI(1)+AI(2)/C+AI(3)*ALOG(EP)+AI(4)*ALOG(RA))*1.155
      IF(INTER.NE.1)GO TO 9839
      WRITE(1,6948)
 6948 FORMAT(/////)
      NPAUX=I-1
      CALL BEEP(20,15)
      VMM=VEL(I-1)*60.
      WRITE(1,9328)NPAUX,HHI,HHF,C,VMM,ES
 9328 FORMAT(' NRO PASSE: ',I2,//,' INITIAL THICKNESS (MM): ',F5.1,/,
     >' FINAL THICKNESS (MM): ',F5.1,/,' MEAN TEMPERATURE (.C): ',F5.0,
     >/,' SPEED (M/MIN): ',F5.1,
     >/,' HOT STRENGTH (KGF/MM2): ',F4.1)
 9839 V=V/1000.
      X=(HI-HF)/HI
      SQL=SQRT(X/(1-X))
      SQ=SQRT(2.*HF/D)
      ALF=TAN(0.392699081*SQ*ALOG(1.-X)+0.5*ATAN(SQL))*SQ
      F=D*ALF*ALF*0.5/HF+1
      Q=0.5*(3.14159*ATAN(SQL)-ALOG(F*F*(1.-X))/SQ)/SQL-0.785398
      P(I-1)=ES*Q*W*SQRT(D*(HI-HF)/2.)
C
C *** CALCULO DO RAIO DEFORMADO.
C
      DL(I)=D*(1.+0.00022*P(I-1)/(W*(HI-HF)))
      D1=DL(I)
C
C *** CALCULO DA PRESSAO, TORQUE E POTENCIA DE LAMINACAO CONSIDERANDO-
C *** SE A CORRECAO DEVIDO `A DEFORMACAO DO RAIO DO CILINDRO.
C
      SQ=SQRT(2.*HF/D1)
      ALF=TAN(0.392699081*SQ*ALOG(1.-X)+0.5*ATAN(SQL))*SQ
      F=D1*ALF*ALF*0.5/HF+1.
      Q=0.5*(3.14159*ATAN(SQL)-ALOG(F*F*(1.-X))/SQ)/SQL-0.785398
      P(I-1)=ES*Q*W*SQRT(D1*(HI-HF)/2.)
      IF(INTER.NE.1)GO TO 3432
      CARGA=P(I-1)/1000.
      WRITE(1,4023)CARGA
 4023 FORMAT(' ROLLING LOAD (T): ',F5.0)
 3432 HN=HF+D*(1.-COS(ALF))
      DFR(I)=(HN*COS(ALF)/HF-1.)*100.
      DRE(I-1)=(1.-HN*COS(ALF)/H1)*100.
C
C *** VERIFICA SE FOI ULTRAPASSADA PRESSAO LIMITE DE LAMINACAO.
C
      IF(P(I-1)-PMAX)11,11,12
   11 FIM=ARCOS(1.-(HI-HF)/D1)
      TORQ(I-1)=ES*D1*D*(FIM/2.-ALF)*W*9.803/2000000.
      IF(INTER.NE.1)GO TO 3895
      TORQU=TORQ(I-1)/9.803
      WRITE(1,4438)TORQU
 4438 FORMAT(' ROLLING TORQUE (T.M): ',F5.1)
C
C *** CALCULO DAS PERDAS POR ATRITO E TRANSMISSAO.
C
 3895 TORINT=9.803*P(I-1)*D1*CFATR/1.E6+TORQ(I-1)
      TORQ(I-1)=TORINT*(1./CTRANS-1.)+TORINT
C
C *** PERDAS DO MOTOR INCLUIDAS NO CALCULO DE POTENCIA.
C
      ERN(I-1)=0.105*TORQ(I-1)*19098.593*VEL(I-1)/D/RMOT
      IF(INTER.NE.1)GO TO 8749
      TORQU=TORQ(I-1)/9.803
      WRITE(1,3489)TORQU,ERN(I-1)
 3489 FORMAT(' TOTAL ROLLING TORQUE (T.M): ',F5.1,/,
     >' TOTAL ROLLING POWER (KW): ',F6.0)
C
C *** VERIFICA SE FOI ULTRAPASSADA POTENCIA LIMITE DE LAMINACAO.
C
 8749 IF(ERN(I-1)-ERMAX)13,12,12
C
C *** FOI ULTRAPASSADA PRESSAO OU POTENCIA LIMITE DE LAMINACAO;
C *** DIMINUI-SE A REDUCAO E EFETUA-SE NOVAMENTE OS CALCULOS.
C ***
C *** NOTE-SE QUE SE A REDUCAO FICAR MENOR QUE UM CERTO VALOR
C *** O ESQUEMA DE PASSES TORNA-SE INVIAVEL DEVIDO `A PROBLEMAS
C *** DE COROAMENTO QUE ACABARAO OCORRENDO NA TIRA.
C
   12 DEH(I-1)=0.9*DEH(I-1)
      LO=LL
      IF(DEH(I-1).GE.ABMIN)GOTO 51
      WRITE(1,1543)DEH(I-1)
 1543 FORMAT(//,' STRAIN LOWER THAN ',F3.1,/)
      GO TO 87
C
C *** VERIFICA SE FOI ULTRAPASSADA ESPESSURA MINIMA DO ESBOCO.
C
   13 IF(HHF-H2)15,15,30
C
C *** SIM, CORRIGE ESPESSURA.
C
   15 HHF=H2
      H(I)=HHF
C
C *** VERIFICA SE A ULTIMA REDUCAO E' PEQUENA DEMAIS;
C *** SE NAO FOR, IMPRIME O ESQUEMA DE PASSES.
C
      IF(((HHI-HHF)/HHI)-RMIN)16,17,17
C
C *** VERIFICA SE HA' NECESSIDADE DE NUMERO IMPAR DE PASSES,
C *** CASO NAO HOUVER, IMPRIME O ESQUEMA.
C
   17 NP=I-1
      IF(NPASS.EQ.0)GO TO 70
C
C *** HA' NECESSIDADE DE UM NUMERO IMPAR DE PASSES; VERIFICA:
C *** SE A CONDICAO FOR SATISFEITA IMPRIME O ESQUEMA; CASO CONTRARIO,
C *** VOLTA A RECALCULAR O ESQUEMA, REDUZINDO AS VELOCIDADES.
C
      DO 19 K=1,NPAS
      IF(NP-NN(K))19,70,19
   19 CONTINUE
C
C *** CALCULO DE NOVO ESQUEMA DE PASSES, REDUZINDO-SE
C *** AS VELOCIDADES DOS CILINDROS.
C
      LO=LL
   16 IF(NK-2)24,25,26
   24 VEL(1)=0.9*VEL(1)
      IF(VEL(1)-VA)27,27,280
  280 VEL(2)=0.95*VEL(2)
      VEL(3)=0.97*VEL(3)
      GOTO 28
   27 NK=2
   25 VEL(2)=0.9*VEL(2)
      IF(VEL(2)-VA)29,29,282
  282 VEL(3)=0.95*VEL(3)
      VEL(4)=0.97*VEL(4)
      GOTO 28
   29 NK=3
   26 VEL(3)=0.9*VEL(3)
      VEL(4)=0.95*VEL(4)
      IF(VEL(3)-VA)31,31,28
   31 VEL(4)=0.95*VEL(4)
C
C *** VERIFICA SE NAO FOI UTILIZADA VELOCIDADE ABAIXO DA MINIMA.
C
      IF(VEL(4)-VA)32,32,28
C
C *** EM CASO AFIRMATIVO, RECALCULA ESQUEMA DIMINUINDO REDUCOES.
C
   32 DH=0.9*DH
      AX=0.99*AX
C
C *** VERIFICA SE FOI MANTIDA REDUCAO MINIMA.
C *** SE ELA NAO FOR MANTIDA, O ESQUEMA DE PASSES E' INVIAVEL.
C
      IF(DH-ABMIN)1537,61,61
 1537 WRITE(1,1539)DH
 1539 FORMAT(//,' AT LEAST ONE OF THE PASSES HAS STRAIN LOWER THAN ',
     >'THE MINIMUM: DH = ',F4.1)
      GO TO 87
   30 CONTINUE
C
C *** CALCULO DE ANGULOS DE MORDIDA E REDUCOES
C *** PARA AS NOVAS VELOCIDADES REDUZIDAS.
C ***
C *** A FORMULA PARA CALCULO DOS ANGULOS DE MORDIDA FOI
C *** DERIVADA A PARTIR DOS DADOS DE SEREDYNSKI.
C
   28 J=NK
      DO 281 II=J,4
      TETA=(25.5-2.*VEL(II))*0.01745329*AX
  281 DEH(II)=D2*(1.-COS(TETA))
      DO 287 II=5,NPAS
  287 DEH(II)=DH
      LO=LAUX
C
C *** PROCEDE AO CALCULO DE NOVO ESQUEMA DE PASSES.
C
      GOTO 60
C
C *** CALCULO DO POSICIONAMENTO DO LAMINADOR DE BORDAS
C *** E PARAFUSO DO LAMINADOR ESBOCADOR.
C
   70 W=W*(1.+ALFA*(TC(NP-2)-25.))
      DO 91 I=1,NP
      WL(I)=(H(I)-H(I+1))*100./H(I)
      R(I)=19098.593*VEL(I)/D2
      PAR(I)=H(I+1)-P(I)/XM
      P(I)=P(I)/1000.
      WW(2*I)=W+50.
      M(I)=I
      TORQ(I)=TORQ(I)/9.803
   91 WW(2*I-1)=W
      WW(NP)=W+50.
C
C *** IMPRESSAO DO ESQUEMA DE PASSES.
C
      DO 1500 I=1,NP
      VMM=VEL(I)*60.
      IF(IS.EQ.2)GO TO 1257
      CALL BEEP(20,15)
 1257 WRITE(IS,719)M(I)
  719 FORMAT(/////,' PASS NUMBER ',I2,//)
      WRITE(IS,720)R(I),VMM,WL(I),H(I),H(I+1),PAR(I),WW(I),P(I),TORQ(I),
     >ERN(I),TC(I),TP(I),DRE(I),DFR(I)
  720 FORMAT(' ROTACAO (RPM) = ',F3.0,' - (M/MIN) = ',F4.0,4X,'STRAIN (
     >%) = ',F3.0,/,' INITIAL THICKNESS (MM) = ',F5.1,10X,'FINAL THICKNESS',
     > (MM) = ',F5.1,/,' ROLL GAP (MM) = ',F5.1,19X,'VERTICAL ROLLING MILL',
     > (MM) = ',F5.0,//,' LOAD (T) = ',F5.0,23X,'TORQUE (T.M) = ',F4.
     >0,/,1X,'POWER (KW) = ',F6.0,//,' HEAD TEMPERATURE (.C) = ',F
     >5.0,9X,'TAIL TEMPERATURE (.C) = ',F5.0,/,' BACKWARD SLIP'' (%) = ',
     >F4.1,19X,'FORWARD SLIP (%) = ',F4.1)
      WRITE(IS,6879)
 6879 FORMAT(5X)
      IF(IS.EQ.2)GO TO 1500
      CALL BEEP(20,15)
      WRITE(1,1490)
 1490 FORMAT(///,' PRESS  TO CONTINUE...')
      READ(1,1495)IE
 1495 FORMAT(A1)
      CALL HOME
 1500 CONTINUE
  759 CALL BEEP(20,15)
      WRITE(1,1499)
 1499 FORMAT(/,' DO YOU WANT TO CALCULATE A NEW PASS SCHEDULE (T/F)? ')
      READ(1,1495)RESP
      IF(RESP)GO TO 1444 
      END

***** End of Program Listing ******

Return to the Software Menu.

Last Update: 28 June 1996
© Antonio Augusto Gorni